Mendapatkan Waktu Secara Remote Menggunakan Visual Basic

Salah seorang teman menanyakan kepada saya bagaimana mendapatkan waktu yang berjalan pada komputer lain secara remote menggunakan Visual Basic (VB). Sayapun menjawab dengan gampang agar dia menggunakan kontrol winsock untuk menkoneksikan program client dan server dan memberikan informasi waktu yang berjalan. Tapi, temenku itu malah mengatakan bahwa dia tidak mau ada program yg ter-install pada komputer yang akan di lihat waktunya.

Awalnya seh saya malas-malasan, karna tidak mau di repotkan dengan kerjaan tambahan. Tapi karna teman, semua harus dilakukan, hehehhee. Lagipula sebelumnya saya juga tidak begitu yakin apakah VB bisa melakukannya. Namun, saya mencoba pada "Windows Command Prompt", dan menggunakan perintah "NET TIME \SERVER" dan sayapun berhasil mendapatkan waktu berjalan pada komputer yang saya tuju.



Command Prompt Windows Menampilkan Waktu Komputer.

Dari sini bisa dipastikan, setidaknya ada library milik windows yang bisa di gunakan oleh VB untuk melakukan tugas ini. Sayapun mulai mencari-cari referensi yang tepat di Internet. Dan sayapun akhirnya menemukan source code yang di madsudkan oleh teman saya itu. Berikut source codenya dan langkah-langkah penggunaannya:
MASUKKAN CODE INI KE DALAM SEBUAH MODUL

Option Explicit
'
'
Private Declare Function NetRemoteTOD Lib "Netapi32.dll" ( _
tServer As Any, pBuffer As Long) As Long
'
Private Type SYSTEMTIME
wYear As Integer
wMonth As Integer
wDayOfWeek As Integer
wDay As Integer
wHour As Integer
wMinute As Integer
wSecond As Integer
wMilliseconds As Integer
End Type
'
Private Type TIME_ZONE_INFORMATION
Bias As Long
StandardName(32) As Integer
StandardDate As SYSTEMTIME
StandardBias As Long
DaylightName(32) As Integer
DaylightDate As SYSTEMTIME
DaylightBias As Long
End Type
'
Private Declare Function GetTimeZoneInformation Lib "kernel32" _
(lpTimeZoneInformation As TIME_ZONE_INFORMATION) As Long
'
Private Declare Function NetApiBufferFree Lib "Netapi32.dll" _
(ByVal lpBuffer As Long) As Long
'
Private Type TIME_OF_DAY_INFO
tod_elapsedt As Long
tod_msecs As Long
tod_hours As Long
tod_mins As Long
tod_secs As Long
tod_hunds As Long
tod_timezone As Long
tod_tinterval As Long
tod_day As Long
tod_month As Long
tod_year As Long
tod_weekday As Long
End Type
'
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
(Destination As Any, Source As Any, ByVal Length As Long)
'
'
Public Function getRemoteTOD(ByVal strServer As String) As Date
'
Dim result As Date
Dim lRet As Long
Dim tod As TIME_OF_DAY_INFO
Dim lpbuff As Long
Dim tServer() As Byte
'
tServer = strServer & vbNullChar
lRet = NetRemoteTOD(tServer(0), lpbuff)
'
If lRet = 0 Then
CopyMemory tod, ByVal lpbuff, Len(tod)
NetApiBufferFree lpbuff
result = DateSerial(tod.tod_year, tod.tod_month, _
tod.tod_day) + _
TimeSerial(tod.tod_hours, tod.tod_mins - tod.tod_timezone, _
tod.tod_secs)
getRemoteTOD = result
Else
Err.Raise Number:=vbObjectError + 1001, _
Description:="cannot get remote TOD"
End If
'
End Function



MASUKKAN CODE INI KE DALAM SEBUAH FORM

Private Sub Command1_Click()
Dim d As Date
'
d = getRemoteTOD("192.168.1.1")
MsgBox d
End Sub


Setelah kamu sudah memasukkan seluruh source code yang ada diatas dengan benar. Silahkan liat baris code yang ada pada form seperti berikut :

d = getRemoteTOD("192.168.1.1")

Silahkan mengganti alamat IP Address"192.168.1.1", dengan alamat IP Address komputer yang ingin kamu liat waktu berjalannya. Bila semua sudah terlengkapi, silahkan jalankan programnya. Jika program berjalan dengan baik maka kamu akan melihat tampilan sebagai berikut :



Hasil Program pada saat di jalankan.

Oke, sebelum saya menutup artikel saya ini. Saya ingin memberitahukan bahwa program ini di uji di atas sistem operasi Windows XP SP2 baik client maupun server. Ada kemungkinan program di atas tidak berjalan dengan normal akibat dari blokir oleh firewall, sistem tidak mendukung service, jaringan tidak terhubung dengan baik (periksa menggunakan ping), dan faktor lainnya.

Akhir kata sekian dulu artikel ini saya sampaikan, semoga bermanfaat. Terima kasih.